BauDataWeb Query Collection

This page presents a set of selected queries for BauDataWeb, the European building and construction materials database for the Semantic Web. To learn more about the project and the individuals who contributed to this project please visit the project landing page at

semantic.eurobau.com

BauDataWeb Dataset Queries

All of the subsequent queries can be executed against the public SPARQL endpoints available at http://linkeddata.uriburner.com/sparql and http://lod.openlinksw.com/sparql.

a) Search for building materials that span more than one FreeClass category, i.e. all products subsumed by the FreeClass code "16000000".

The SPARQL query implements transitive closure using a custom Virtuoso Open Source extension. By comparison, similar results would be achieved with the property path feature provided by SPARQL 1.1, as currently commented out in the query. Finally, as a last alternative, reasoning using RDFS-entailment rules could be enabled.

PREFIX fc: <http://www.freeclass.eu/freeclass_v1#>
SELECT DISTINCT ?fc_gen as ?freeclass_class_id ?product_model_variant ?product_model
WHERE {
	?product_model_variant a ?fc_gen .
	?product_model_variant gr:isVariantOf ?product_model .
	?fc_tax fc:hierarchyCode "16000000" .
	?fc_gen rdfs:subClassOf ?fc_tax OPTION(transitive) .
	# using the property path feature of SPARQL 1.1 instead
	# ?fc_gen rdfs:subClassOf+ ?fc_tax .
	OPTIONAL { ?fc_gen fc:hierarchyCode ?code }
	FILTER(!bound(?code))
}
LIMIT 10

Output

b) Query materials and offers that meet specific criteria, i.e. constraints on properties and attributes.

PREFIX fc: <http://www.freeclass.eu/freeclass_v1#>
PREFIX gr: <http://purl.org/goodrelations/v1#>
PREFIX vcard: <http://www.w3.org/2006/vcard/ns#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX ebu: <http://semantic.eurobau.com/eurobau-utility.owl#>

SELECT DISTINCT ?offer ?product_model ?product_model_name
WHERE {
	?offer a gr:Offering .
	?offer gr:includesObject [gr:typeOfGood ?product] .
	?product gr:hasMakeAndModel ?product_model .
    ?offer gr:eligibleCustomerTypes gr:Enduser .
    ?product_model a ?fc_gen .
    ?product_model a gr:ProductOrServiceModel .
    ?product_model rdfs:label ?product_model_name .
    ?fc_tax fc:hierarchyCode "14101010" .
    ?fc_gen rdfs:subClassOf ?fc_tax .
    ?product_model fc:P_2 [gr:hasValueFloat ?min_value_P_2] .
    FILTER(?min_value_P_2 >= 200) # length >= 200 centimeters
    ?product_model fc:P_3 [gr:hasValueFloat ?min_value_P_3] .
    FILTER(?min_value_P_3 >= 50) # width >= 50 centimeters
    ?product_model fc:P_E83 fc:V_W803 . # range of application: formwork inlet
}
ORDER BY ?product_model_name
LIMIT 10

Output

c) Federated query that combines the BauDataWeb dataset with data from DBPedia.

The following query selects offers for plan clay blocks (FreeClass code "12201010") with a strength of 38. We use query federation to gather additional geo-positional information from DBPedia. The places from DBPedia serve to augment the BauDataWeb dataset by details about interesting places in the neighborhood of the warehouse locations where the building and construction material can be purchased from. The adjacent places are selected based on geo coordinates within a predefined threshold.

PREFIX gr: <http://purl.org/goodrelations/v1#>
PREFIX fc: <http://www.freeclass.eu/freeclass_v1#>
PREFIX vcard: <http://www.w3.org/2006/vcard/ns#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>

SELECT DISTINCT ?dbpedia_place ?dbpedia_place_name ?location ?location_name ?offer ?product_model_name
WHERE {
	?offer a gr:Offering .
	?offer gr:includesObject [gr:typeOfGood ?product] .
	?product gr:hasMakeAndModel ?product_model .
	?offer gr:availableAtOrFrom ?location .
	?location rdfs:label ?location_name .
	?location vcard:geo [vcard:longitude ?long; vcard:latitude ?lat] .
	?product_model a ?fc_gen .
	?product_model a gr:ProductOrServiceModel .
	?product_model rdfs:label ?product_model_name .
	?fc_gen rdfs:subClassOf ?fc_tax .
	?fc_tax fc:hierarchyCode "12201010" .
	?product_model fc:P_4 [gr:hasValueFloat ?value_P_4] .
	FILTER(?value_P_4 = 38)
  
	SERVICE <http://dbpedia.org/sparql> {
		?dbpedia_place a <http://dbpedia.org/ontology/Place> .
        ?dbpedia_place rdfs:label ?dbpedia_place_name .
    	?dbpedia_place geo:lat ?lat2 .
	    ?dbpedia_place geo:long ?long2 .
        FILTER(lang(?dbpedia_place_name) = "en" && ?lat2 > 47.0 && ?lat2 < 48.5 && ?long2 > 11.3 && ?long2 < 16.4)
    }

    FILTER(ABS(?lat2-?lat) < 0.05 && ABS(?long2-?long) < 0.05)
}
LIMIT 10

Output

d) Search for plan clay blocks (FreeClass code "12201010") with a strength of 38 centimeters. This query is the one provided on the project landing page, with some variable renaming taken effect.

PREFIX gr: <http://purl.org/goodrelations/v1#>
PREFIX fc: <http://www.freeclass.eu/freeclass_v1#>
PREFIX vcard: <http://www.w3.org/2006/vcard/ns#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

SELECT DISTINCT ?offer ?location ?location_name ?location_url ?long ?lat ?product_model ?product_model_name ?offer_link
WHERE {
	?offer a gr:Offering .
	?offer gr:includesObject [gr:typeOfGood ?product] .
	?product gr:hasMakeAndModel ?product_model .
	?offer gr:availableAtOrFrom ?location .
	?location rdfs:label ?location_name .
	?location vcard:geo [vcard:longitude ?long; vcard:latitude ?lat] .
	?location vcard:adr [vcard:url ?location_url] .
	?offer foaf:page ?offer_link .
	?product_model a ?fc_gen .
	?product_model a gr:ProductOrServiceModel .
	?product_model rdfs:label ?product_model_name .
	?fc_gen rdfs:subClassOf ?fc_tax .
	?fc_tax fc:hierarchyCode "12201010" .
	?product_model fc:P_4 [gr:hasValueFloat ?value_P_4] .
	FILTER(?value_P_4 = 38)
}
ORDER BY ?location ?product_model_name
LIMIT 10

Output